[教学]：多义线宽格式刷。

eachy

API中Getentdxf得到的点是WCS点，程序中用到了WCS到UCS的矩阵转换。

2. ;|
   
3. 命令: c:plw_match
   
4. 
   
5. 功能: 多义线宽度格式刷，可以刷Lwployline,ployline,Line,Arc,Circle
   
6. 
   
7. 说明:  配合XDRX_API使用
   
8.        对程序的建议请到“晓东CAD空间”－论坛，[url]www.xdcad.net/forum留言[/url]
   
9. |;
   
10. (DEFUN C:plw_match (/ e wid ss cen rad d1 d2 ent xform)
    
11.   (if (setq e (xdrx_entsel "\n请选择匹配源<退出>:" '(0 . "*POLYLINE")))
    
12.     (progn
    
13.       (xdrx_begin)
    
14.       (xdrx_ucson)
    
15.       (setq wid (xdrx_getentdxf 40))
    
16.       (princ (strcat "\n线宽=" (rtos wid 2 2)))
    
17.       (princ "\n选择需要匹配的实体<退出>:")
    
18.       (if (setq ss (ssget '((0 . "*POLYLINE,LINE,ARC,CIRCLE"))))
    
19.         (progn
    
20.           (xdrx_setsstodb ss 0)
    
21.           (while (setq ent (xdrx_getentdata 0))
    
22.             (cond
    
23.               ((or (= (xdrx_getentdxf 0) "POLYLINE")
    
24.                    (= (xdrx_getentdxf 0) "LWPOLYLINE")
    
25.                )
    
26.                (command "pedit" ent "w" wid "")
    
27.               )
    
28.               ((or (= (xdrx_getentdxf 0) "LINE")
    
29.                    (= (xdrx_getentdxf 0) "ARC")
    
30.                )
    
31.                (command "pedit" ent "y" "w" wid "")
    
32.               )
    
33.               (T
    
34.                (progn
    
35.                  (setq cen (xdrx_getentdxf 10)
    
36.                        rad (xdrx_getentdxf 40)
    
37.                        d1  (- (* 2 rad) wid)
    
38.                        d2  (+ (* 2 rad) wid)
    
39.                  )
    
40.                               ;;WCS->当前UCS转换
    
41.                  (setq xForm (xdrx_matrix_wcs2ucs))
    
42.                  (setq cen (xdrx_point_transform cen xForm))
    
43.                  (command "donut" d1 d2 cen "")
    
44.                  (entdel ent)
    
45.                )
    
46.               )
    
47.             )
    
48.           )
    
49.         )
    
50.       )
    
51.       (xdrx_ucsoff)
    
52.       (xdrx_end)
    
53.     )
    
54.   )
    
55.   (princ)
    
56. )

;|<br /> 命令: c:plw_match<br /> <br /> 功能: 多义线宽度格式刷，可以刷Lwployline,ployline,Line,Arc,Circle<br /> <br /> 说明:  配合XDRX_API使用<br />        对程序的建议请到“晓东CAD空间”－论坛，[url]www.xdcad.net/forum留言[/url]<br /> |;<br /> (DEFUN C:plw_match (/ e wid ss cen rad d1 d2 ent xform)<br />   (if (setq e (xdrx_entsel "\n请选择匹配源<退出>:" '(0 . "*POLYLINE")))<br />     (progn<br />       (xdrx_begin)<br />       (xdrx_ucson)<br />       (setq wid (xdrx_getentdxf 40))<br />       (princ (strcat "\n线宽=" (rtos wid 2 2)))<br />       (princ "\n选择需要匹配的实体<退出>:")<br />       (if (setq ss (ssget '((0 . "*POLYLINE,LINE,ARC,CIRCLE"))))<br />         (progn<br />           (xdrx_setsstodb ss 0)<br />           (while (setq ent (xdrx_getentdata 0))<br />             (cond<br />               ((or (= (xdrx_getentdxf 0) "POLYLINE")<br />                    (= (xdrx_getentdxf 0) "LWPOLYLINE")<br />                )<br />                (command "pedit" ent "w" wid "")<br />               )<br />               ((or (= (xdrx_getentdxf 0) "LINE")<br />                    (= (xdrx_getentdxf 0) "ARC")<br />                )<br />                (command "pedit" ent "y" "w" wid "")<br />               )<br />               (T<br />                (progn<br />                  (setq cen (xdrx_getentdxf 10)<br />                        rad (xdrx_getentdxf 40)<br />                        d1  (- (* 2 rad) wid)<br />                        d2  (+ (* 2 rad) wid)<br />                  )<br />                               ;;WCS->当前UCS转换<br />                  (setq xForm (xdrx_matrix_wcs2ucs))<br />                  (setq cen (xdrx_point_transform cen xForm))<br />                  (command "donut" d1 d2 cen "")<br />                  (entdel ent)<br />                )<br />               )<br />             )<br />           )<br />         )<br />       )<br />       (xdrx_ucsoff)<br />       (xdrx_end)<br />     )<br />   )<br />   (princ)<br /> )

ll_j

也贴一个刷子，纯Lisp程序，就是长一点。

[php](princ "\n**宽度格式刷,自由软件,版本号 1.00,作者：南京市市政设计研究院 嵇龙。**" )

(defun sz_s()
  (setq wd1 "\n当前匹配属性：" wd0 "不匹配属性：")
  (if (= sz_color 1) (setq wd1 (strcat wd1 " 颜色")) (setq wd0 (strcat wd0 " 颜色")))
  (if (= sz_layer 1) (setq wd1 (strcat wd1 " 图层")) (setq wd0 (strcat wd0 " 图层")))
  (if (= sz_ltype 1) (setq wd1 (strcat wd1 " 线形")) (setq wd0 (strcat wd0 " 线形")))
  (if (= sz_ltsca 1) (setq wd1 (strcat wd1 " 线形比例")) (setq wd0 (strcat wd0 " 线形比例")))
  (if (= sz_asywh 1) (setq wd1 (strcat wd1 " 变宽线形")) (setq wd0 (strcat wd0 " 变宽线形")))
  (if (= wd1 "\n当前匹配属性：") (setq wd1 "\n当前匹配属性：宽度")(setq wd1 (strcat wd1 "。")))
  (if (= wd0 "不匹配属性：") (setq wd0 "") (setq wd0 (strcat wd0 "。")))
  (princ (strcat "\n***" wd1 wd0))
  (initget "1 2 3 4 5")
  (setq setk(getkword "\n改变：颜色1/图层2/线形3/线形比例4/变宽线形5/<确认>："))
  (cond
    ((= setk "1") (if (= sz_color 1) (setq sz_color 0) (setq sz_color 1)) (sz_s))
    ((= setk "2") (if (= sz_layer 1) (setq sz_layer 0) (setq sz_layer 1)) (sz_s))
    ((= setk "3") (if (= sz_ltype 1) (setq sz_ltype 0) (setq sz_ltype 1)) (sz_s))
    ((= setk "4") (if (= sz_ltsca 1) (setq sz_ltsca 0) (setq sz_ltsca 1)) (sz_s))
    ((= setk "5") (if (= sz_asywh 1) (setq sz_asywh 0) (setq sz_asywh 1)) (sz_s))
    (t nil)
  )
)

(defun sz_b(num enum um / j b0 bj)
  (if (and (assoc num ei) enum)
    (setq ei (subst enum (assoc num ei) ei))
    (if enum
      (setq ei (reverse (cons enum (reverse ei))))
      (if (assoc num ei)
        (progn
          (setq j -1
                b0 nil
          )
          (repeat (length ei)
            (setq j (1+ j)
                  bj(nth j ei)
            )
            (if (/= bj (assoc num ei))
              (setq b0 (cons bj b0))
              (if um (setq b0 (cons (cons num um) b0)))
            )
          )
          (setq ei (reverse b0))
        )
      )
    )
  )
)

(defun sz_main()
  (setq len (sslength ss1)
        i   -1
        ent0(entget (car ent1))
        e62 (assoc 62 ent0)
        e8  (assoc 8 ent0)
        e6  (assoc 6 ent0)
        e48 (assoc 48 ent0)
        e43 (assoc 43 ent0)
        e90 (cdr (assoc 90 ent0))
  )
  (if (>= e90 3)
    (progn
      (repeat 3 (setq ent0 (subst (cons 11 (cdr (assoc 10 ent0))) (assoc 10 ent0) ent0)))
      (setq ent0 (reverse ent0)
            ent0 (reverse (cons (car ent0) (cdr (member (assoc 11 ent0) ent0))))
            ent0 (subst '(90 . 2) (assoc 90 ent0) ent0)
      )
      (repeat 2 (setq ent0 (subst (cons 10 (cdr (assoc 11 ent0))) (assoc 11 ent0) ent0)))
    )
  )
  (repeat len
    (setq i (1+ i)
          eni (ssname ss1 i)
          ei  (entget eni)
    )
    (cond
      ((= (cdr (assoc 0 ei)) "LWPOLYLINE")
       (sz_lwp)
      )
      ((= (cdr (assoc 0 ei)) "LINE")
       (sz_line)
      )
      ((= (cdr (assoc 0 ei)) "ARC")
       (sz_arc)
      )
      ((= (cdr (assoc 0 ei)) "CIRCLE")
       (sz_circle)
      )
      (t nil)
    )
  )
)

(defun sz_lwp()
  (if (= sz_color 1) (sz_b 62 e62 256))
  (if (= sz_layer 1) (setq ei (subst e8 (assoc 8 ei) ei)))
  (if (= sz_ltype 1) (sz_b 6 e6 "BYLAYER"))
  (if (= sz_ltsca 1) (sz_b 48 e48 1.0))
  (if (assoc 43 ei)
    (setq ei (subst e43 (assoc 43 ei) ei))
    (if (= sz_asywh 1)
      (setq ei (reverse (cons e43 (reverse ei))))
    )
  )
  (entmod ei)
  (entupd eni)
)

(defun sz_line(/ ei62 ei8 ei6 ei48 ei10 ei11)
  (setq ei62 (assoc 62 ei)
        ei8  (assoc 8 ei)
        ei6  (assoc 6 ei)
        ei48 (assoc 48 ei)
        ei10 (assoc 10 ei)
        ei11 (assoc 11 ei)
  )
  (setq ei (subst (assoc 5 ei) (assoc 5 ent0) ent0)
        ei (subst (cons 70 0) (assoc 70 ei) ei)
  )
  (if (= sz_color 0) (sz_b 62 ei62 256))
  (if (= sz_layer 0) (setq ei (subst ei8 (assoc 8 ei) ei)))
  (if (= sz_ltype 0) (sz_b 6 ei6 "BYLAYER"))
  (if (= sz_ltsca 0) (sz_b 48 ei48 1.0))
  (setq ei (subst (cons 12 (cdr ei10)) (assoc 10 ei) ei)
        ei (subst (cons 10 (cdr ei11)) (assoc 10 ei) ei)
        ei (subst ei10 (assoc 12 ei) ei)
  )
  (repeat 2 (setq ei (subst (cons 42 0.0) (assoc 42 ei) ei)))
  (entdel eni)
  (entmake ei)
)

(defun sz_circle(/ ei62 ei8 ei6 ei48 ei10 ei40 pt1 pt2)
  (setq ei62 (assoc 62 ei)
        ei8  (assoc 8 ei)
        ei6  (assoc 6 ei)
        ei48 (assoc 48 ei)
        ei10 (cdr (assoc 10 ei))
        ei40 (cdr (assoc 40 ei))
        pt1  (cons (- (car ei10) ei40) (cdr ei10))
        pt2  (cons (+ (car ei10) ei40) (cdr ei10))
  )
  (setq ei (subst (assoc 5 ei) (assoc 5 ent0) ent0)
        ei (subst (cons 70 1) (assoc 70 ei) ei)
  )
  (if (= sz_color 0) (sz_b 62 ei62 256))
  (if (= sz_layer 0) (setq ei (subst ei8 (assoc 8 ei) ei)))
  (if (= sz_ltype 0) (sz_b 6 ei6 "BYLAYER"))
  (if (= sz_ltsca 0) (sz_b 48 ei48 1.0))
  (setq ei (subst (cons 12 pt1) (assoc 10 ei) ei)
        ei (subst (cons 10 pt2) (assoc 10 ei) ei)
        ei (subst (cons 10 pt1) (assoc 12 ei) ei)
  )
  (repeat 2 (setq ei (subst (cons 42 1.0) (assoc 42 ei) ei)))
  (entdel eni)
  (entmake ei)
)

(defun sz_arc(/ ei62 ei8 ei6 ei10 ei48 ei40 ei50 ei51 pt1 pt2 lpt alf e42)
  (setq ei62 (assoc 62 ei)
        ei8  (assoc 8 ei)
        ei6  (assoc 6 ei)
        ei48 (assoc 48 ei)
        ei10 (cdr (assoc 10 ei))
        ei40 (cdr (assoc 40 ei))
        ei50 (cdr (assoc 50 ei))
        ei51 (cdr (assoc 51 ei))
        pt1  (list (+ (car ei10) (* ei40 (cos ei50)))
                   (+ (cadr ei10) (* ei40 (sin ei50))) (caddr ei10))
        pt2  (list (+ (car ei10) (* ei40 (cos ei51)))
                   (+ (cadr ei10) (* ei40 (sin ei51))) (caddr ei10))
        lpt  (/ (distance pt1 pt2) 2.0)
        alf  (- ei51 ei50)
  )
  (setq ei (subst (assoc 5 ei) (assoc 5 ent0) ent0)
        ei (subst (cons 70 0) (assoc 70 ei) ei)
  )
  (if (= sz_color 0) (sz_b 62 ei62 256))
  (if (= sz_layer 0) (setq ei (subst ei8 (assoc 8 ei) ei)))
  (if (= sz_ltype 0) (sz_b 6 ei6 "BYLAYER"))
  (if (= sz_ltsca 0) (sz_b 48 ei48 1.0))
  (setq ei (subst (cons 12 pt1) (assoc 10 ei) ei)
        ei (subst (cons 10 pt2) (assoc 10 ei) ei)
        ei (subst (cons 10 pt1) (assoc 12 ei) ei)
  )
  (if (or (> alf pi) (and (< alf 0) (> alf (- pi))))
    (setq e42 (/ (+ ei40 (sqrt (- (* ei40 ei40) (* lpt lpt)))) lpt)
          ei  (subst (cons 42 e42) (assoc 42 ei) ei)
    )
    (setq e42 (/ (- ei40 (sqrt (- (* ei40 ei40) (* lpt lpt)))) lpt)
          ei  (subst (cons 42 e42) (assoc 42 ei) ei)
    )
  )
  (entdel eni)
  (entmake ei)
)

(defun sz_ss()
  (setq wd1 "\n当前匹配属性：" wd0 "不匹配属性：")
  (if (= sz_color 1) (setq wd1 (strcat wd1 " 颜色")) (setq wd0 (strcat wd0 " 颜色")))
  (if (= sz_layer 1) (setq wd1 (strcat wd1 " 图层")) (setq wd0 (strcat wd0 " 图层")))
  (if (= sz_ltype 1) (setq wd1 (strcat wd1 " 线形")) (setq wd0 (strcat wd0 " 线形")))
  (if (= sz_ltsca 1) (setq wd1 (strcat wd1 " 线形比例")) (setq wd0 (strcat wd0 " 线形比例")))
  (if (= sz_asywh 1) (setq wd1 (strcat wd1 " 变宽线形")) (setq wd0 (strcat wd0 " 变宽线形")))
  (if (= wd1 "\n当前匹配属性：") (setq wd1 "\n当前匹配属性：宽度")(setq wd1 (strcat wd1 "。")))
  (if (= wd0 "不匹配属性：") (setq wd0 "") (setq wd0 (strcat wd0 "。")))
  (princ (strcat "\n***" wd1 wd0))
  (initget "Setting  ")
  (setq ent1(entsel "\n设置匹配属性S/<拾取参考宽度多义线：>"))
  (if (= ent1 "Setting")
    (progn
      (sz_s)
      (sz_ss)
    )
    (progn
      (if ent1
        (if (/= (type ent1) 'STR)
          (progn
            (if (/= (cdr (assoc 0 (entget (car ent1)))) "LWPOLYLINE") (sz_ss))
            (if (not (assoc 43 (entget (car ent1)))) (sz_ss))
          )
        )
        (sz_ss)
      )
    )
  )
)

(defun c:sz(/ ent1 ent0 wd0 wd1 setk ss1 len i e62 e8 e6 e48 e90 e43 ei eni)
  (command "color" (getvar "cecolor"))
  (if (not sz_color) (setq sz_color 1))
  (if (not sz_layer) (setq sz_layer 1))
  (if (not sz_ltype) (setq sz_ltype 1))
  (if (not sz_ltsca) (setq sz_ltsca 1))
  (if (not sz_asywh) (setq sz_asywh 0))
  (sz_ss)
  (if (/= (type ent1) 'STR)
    (progn
      (princ "\n拾取欲变宽度的线实体：")
      (setq ss1 (ssget '((-4 . "<OR")(0 . "CIRCLE")(0 . "LINE")(0 . "ARC")(0 . "LWPOLYLINE")(-4 . "OR>"))))  
      (if ss1
        (sz_main)
      )
    )
  )
  (princ)
)
[/php]

eachy

下一版的工具箱中提供的【加粗曲线】将格式刷与加粗合二为一了，加粗时可以选择[1.加粗宽度/2 变比]，对出图时改变比例很方便了。可以加宽spline，椭圆。

zzt21963

谢谢分享好程序

yfywk

最初由 ll_j 发布
[B]也贴一个刷子，纯Lisp程序，就是长一点。 [/B]

怎么下载不了？！

自由的鱼

都是好程序！！

hust_laohu

我有个工具可以自由的改变线宽
所以上面的程序我还是不用了
呵呵！

天浪风沙

很好。
就是高手啊。
谢谢

whcdy

最初由 hust_laohu 发布
[B]我有个工具可以自由的改变线宽
所以上面的程序我还是不用了
呵呵！ [/B]

线宽格式刷与自由改变线宽还是有很大不同的，各有千秋！

kissme1029

看不明白

xsshhl

我用普通的刷子，只能传递颜色，线宽无法传递，试试这里的工具，或许有启发。呵呵
-----
嵇龙的好用，plw_match我没有装XDRX_API，用不了。推荐嵇龙，good

又错了

好，本人下载了，用过后，一个字，好，谢谢分享！

yingxy28

好东西

bluesky1000

用过了，真不错！

hyk123

感谢楼主，努力学习